home *** CD-ROM | disk | FTP | other *** search
/ Micromanía 93 / CDMM_93_2.ISO / Project Nomads / nomads_demo_eng.exe / PACKAGE.TCL < prev    next >
Encoding:
Text File  |  2000-12-15  |  20.1 KB  |  649 lines
  1. # package.tcl --
  2. #
  3. # utility procs formerly in init.tcl which can be loaded on demand
  4. # for package management.
  5. #
  6. # RCS: @(#) $Id: package.tcl,v 1.1 2000/12/15 20:10:58 floh Exp $
  7. #
  8. # Copyright (c) 1991-1993 The Regents of the University of California.
  9. # Copyright (c) 1994-1998 Sun Microsystems, Inc.
  10. #
  11. # See the file "license.terms" for information on usage and redistribution
  12. # of this file, and for a DISCLAIMER OF ALL WARRANTIES.
  13. #
  14.  
  15. # Create the package namespace
  16. namespace eval ::pkg {
  17. }
  18.  
  19. # pkg_compareExtension --
  20. #
  21. #  Used internally by pkg_mkIndex to compare the extension of a file to
  22. #  a given extension. On Windows, it uses a case-insensitive comparison
  23. #  because the file system can be file insensitive.
  24. #
  25. # Arguments:
  26. #  fileName    name of a file whose extension is compared
  27. #  ext        (optional) The extension to compare against; you must
  28. #        provide the starting dot.
  29. #        Defaults to [info sharedlibextension]
  30. #
  31. # Results:
  32. #  Returns 1 if the extension matches, 0 otherwise
  33.  
  34. proc pkg_compareExtension { fileName {ext {}} } {
  35.     global tcl_platform
  36.     if {![string length $ext]} {set ext [info sharedlibextension]}
  37.     if {[string equal $tcl_platform(platform) "windows"]} {
  38.         return [string equal -nocase [file extension $fileName] $ext]
  39.     } else {
  40.         # Some unices add trailing numbers after the .so, so
  41.         # we could have something like '.so.1.2'.
  42.         set root $fileName
  43.         while {1} {
  44.             set currExt [file extension $root]
  45.             if {[string equal $currExt $ext]} {
  46.                 return 1
  47.             } 
  48.  
  49.         # The current extension does not match; if it is not a numeric
  50.         # value, quit, as we are only looking to ignore version number
  51.         # extensions.  Otherwise we might return 1 in this case:
  52.         #        pkg_compareExtension foo.so.bar .so
  53.         # which should not match.
  54.  
  55.         if { ![string is integer -strict [string range $currExt 1 end]] } {
  56.         return 0
  57.         }
  58.             set root [file rootname $root]
  59.     }
  60.     }
  61. }
  62.  
  63. # pkg_mkIndex --
  64. # This procedure creates a package index in a given directory.  The
  65. # package index consists of a "pkgIndex.tcl" file whose contents are
  66. # a Tcl script that sets up package information with "package require"
  67. # commands.  The commands describe all of the packages defined by the
  68. # files given as arguments.
  69. #
  70. # Arguments:
  71. # -direct        (optional) If this flag is present, the generated
  72. #            code in pkgMkIndex.tcl will cause the package to be
  73. #            loaded when "package require" is executed, rather
  74. #            than lazily when the first reference to an exported
  75. #            procedure in the package is made.
  76. # -verbose        (optional) Verbose output; the name of each file that
  77. #            was successfully rocessed is printed out. Additionally,
  78. #            if processing of a file failed a message is printed.
  79. # -load pat        (optional) Preload any packages whose names match
  80. #            the pattern.  Used to handle DLLs that depend on
  81. #            other packages during their Init procedure.
  82. # dir -            Name of the directory in which to create the index.
  83. # args -        Any number of additional arguments, each giving
  84. #            a glob pattern that matches the names of one or
  85. #            more shared libraries or Tcl script files in
  86. #            dir.
  87.  
  88. proc pkg_mkIndex {args} {
  89.     global errorCode errorInfo
  90.     set usage {"pkg_mkIndex ?-direct? ?-verbose? ?-load pattern? ?--? dir ?pattern ...?"};
  91.  
  92.     set argCount [llength $args]
  93.     if {$argCount < 1} {
  94.     return -code error "wrong # args: should be\n$usage"
  95.     }
  96.  
  97.     set more ""
  98.     set direct 1
  99.     set doVerbose 0
  100.     set loadPat ""
  101.     for {set idx 0} {$idx < $argCount} {incr idx} {
  102.     set flag [lindex $args $idx]
  103.     switch -glob -- $flag {
  104.         -- {
  105.         # done with the flags
  106.         incr idx
  107.         break
  108.         }
  109.         -verbose {
  110.         set doVerbose 1
  111.         }
  112.         -lazy {
  113.         set direct 0
  114.         append more " -lazy"
  115.         }
  116.         -direct {
  117.         append more " -direct"
  118.         }
  119.         -load {
  120.         incr idx
  121.         set loadPat [lindex $args $idx]
  122.         append more " -load $loadPat"
  123.         }
  124.         -* {
  125.         return -code error "unknown flag $flag: should be\n$usage"
  126.         }
  127.         default {
  128.         # done with the flags
  129.         break
  130.         }
  131.     }
  132.     }
  133.  
  134.     set dir [lindex $args $idx]
  135.     set patternList [lrange $args [expr {$idx + 1}] end]
  136.     if {[llength $patternList] == 0} {
  137.     set patternList [list "*.tcl" "*[info sharedlibextension]"]
  138.     }
  139.  
  140.     set oldDir [pwd]
  141.     cd $dir
  142.  
  143.     if {[catch {eval glob $patternList} fileList]} {
  144.     global errorCode errorInfo
  145.     cd $oldDir
  146.     return -code error -errorcode $errorCode -errorinfo $errorInfo $fileList
  147.     }
  148.     foreach file $fileList {
  149.     # For each file, figure out what commands and packages it provides.
  150.     # To do this, create a child interpreter, load the file into the
  151.     # interpreter, and get a list of the new commands and packages
  152.     # that are defined.
  153.  
  154.     if {[string equal $file "pkgIndex.tcl"]} {
  155.         continue
  156.     }
  157.  
  158.     # Changed back to the original directory before initializing the
  159.     # slave in case TCL_LIBRARY is a relative path (e.g. in the test
  160.     # suite). 
  161.  
  162.     cd $oldDir
  163.     set c [interp create]
  164.  
  165.     # Load into the child any packages currently loaded in the parent
  166.     # interpreter that match the -load pattern.
  167.  
  168.     foreach pkg [info loaded] {
  169.         if {! [string match $loadPat [lindex $pkg 1]]} {
  170.         continue
  171.         }
  172.         if {[catch {
  173.         load [lindex $pkg 0] [lindex $pkg 1] $c
  174.         } err]} {
  175.         if {$doVerbose} {
  176.             tclLog "warning: load [lindex $pkg 0] [lindex $pkg 1]\nfailed with: $err"
  177.         }
  178.         } elseif {$doVerbose} {
  179.         tclLog "loaded [lindex $pkg 0] [lindex $pkg 1]"
  180.         }
  181.         if {[string equal [lindex $pkg 1] "Tk"]} {
  182.         # Withdraw . if Tk was loaded, to avoid showing a window.
  183.         $c eval [list wm withdraw .]
  184.         }
  185.     }
  186.     cd $dir
  187.  
  188.     $c eval {
  189.         # Stub out the package command so packages can
  190.         # require other packages.
  191.  
  192.         rename package __package_orig
  193.         proc package {what args} {
  194.         switch -- $what {
  195.             require { return ; # ignore transitive requires }
  196.             default { eval __package_orig {$what} $args }
  197.         }
  198.         }
  199.         proc tclPkgUnknown args {}
  200.         package unknown tclPkgUnknown
  201.  
  202.         # Stub out the unknown command so package can call
  203.         # into each other during their initialilzation.
  204.  
  205.         proc unknown {args} {}
  206.  
  207.         # Stub out the auto_import mechanism
  208.  
  209.         proc auto_import {args} {}
  210.  
  211.         # reserve the ::tcl namespace for support procs
  212.         # and temporary variables.  This might make it awkward
  213.         # to generate a pkgIndex.tcl file for the ::tcl namespace.
  214.  
  215.         namespace eval ::tcl {
  216.         variable file        ;# Current file being processed
  217.         variable direct        ;# -direct flag value
  218.         variable x        ;# Loop variable
  219.         variable debug        ;# For debugging
  220.         variable type        ;# "load" or "source", for -direct
  221.         variable namespaces    ;# Existing namespaces (e.g., ::tcl)
  222.         variable packages    ;# Existing packages (e.g., Tcl)
  223.         variable origCmds    ;# Existing commands
  224.         variable newCmds    ;# Newly created commands
  225.         variable newPkgs {}    ;# Newly created packages
  226.         }
  227.     }
  228.  
  229.     $c eval [list set ::tcl::file $file]
  230.     $c eval [list set ::tcl::direct $direct]
  231.  
  232.     # Download needed procedures into the slave because we've
  233.     # just deleted the unknown procedure.  This doesn't handle
  234.     # procedures with default arguments.
  235.  
  236.     foreach p {pkg_compareExtension} {
  237.         $c eval [list proc $p [info args $p] [info body $p]]
  238.     }
  239.  
  240.     if {[catch {
  241.         $c eval {
  242.         set ::tcl::debug "loading or sourcing"
  243.  
  244.         # we need to track command defined by each package even in
  245.         # the -direct case, because they are needed internally by
  246.         # the "partial pkgIndex.tcl" step above.
  247.  
  248.         proc ::tcl::GetAllNamespaces {{root ::}} {
  249.             set list $root
  250.             foreach ns [namespace children $root] {
  251.             eval lappend list [::tcl::GetAllNamespaces $ns]
  252.             }
  253.             return $list
  254.         }
  255.  
  256.         # init the list of existing namespaces, packages, commands
  257.  
  258.         foreach ::tcl::x [::tcl::GetAllNamespaces] {
  259.             set ::tcl::namespaces($::tcl::x) 1
  260.         }
  261.         foreach ::tcl::x [package names] {
  262.             set ::tcl::packages($::tcl::x) 1
  263.         }
  264.         set ::tcl::origCmds [info commands]
  265.  
  266.         # Try to load the file if it has the shared library
  267.         # extension, otherwise source it.  It's important not to
  268.         # try to load files that aren't shared libraries, because
  269.         # on some systems (like SunOS) the loader will abort the
  270.         # whole application when it gets an error.
  271.  
  272.         if {[pkg_compareExtension $::tcl::file [info sharedlibextension]]} {
  273.             # The "file join ." command below is necessary.
  274.             # Without it, if the file name has no \'s and we're
  275.             # on UNIX, the load command will invoke the
  276.             # LD_LIBRARY_PATH search mechanism, which could cause
  277.             # the wrong file to be used.
  278.  
  279.             set ::tcl::debug loading
  280.             load [file join . $::tcl::file]
  281.             set ::tcl::type load
  282.         } else {
  283.             set ::tcl::debug sourcing
  284.             source $::tcl::file
  285.             set ::tcl::type source
  286.         }
  287.  
  288.         # As a performance optimization, if we are creating 
  289.         # direct load packages, don't bother figuring out the 
  290.         # set of commands created by the new packages.  We 
  291.         # only need that list for setting up the autoloading 
  292.         # used in the non-direct case.
  293.         if { !$::tcl::direct } {
  294.             # See what new namespaces appeared, and import commands
  295.             # from them.  Only exported commands go into the index.
  296.             
  297.             foreach ::tcl::x [::tcl::GetAllNamespaces] {
  298.             if {! [info exists ::tcl::namespaces($::tcl::x)]} {
  299.                 namespace import -force ${::tcl::x}::*
  300.             }
  301.  
  302.             # Figure out what commands appeared
  303.             
  304.             foreach ::tcl::x [info commands] {
  305.                 set ::tcl::newCmds($::tcl::x) 1
  306.             }
  307.             foreach ::tcl::x $::tcl::origCmds {
  308.                 catch {unset ::tcl::newCmds($::tcl::x)}
  309.             }
  310.             foreach ::tcl::x [array names ::tcl::newCmds] {
  311.                 # determine which namespace a command comes from
  312.                 
  313.                 set ::tcl::abs [namespace origin $::tcl::x]
  314.                 
  315.                 # special case so that global names have no leading
  316.                 # ::, this is required by the unknown command
  317.                 
  318.                 set ::tcl::abs \
  319.                     [lindex [auto_qualify $::tcl::abs ::] 0]
  320.                 
  321.                 if {[string compare $::tcl::x $::tcl::abs]} {
  322.                 # Name changed during qualification
  323.                 
  324.                 set ::tcl::newCmds($::tcl::abs) 1
  325.                 unset ::tcl::newCmds($::tcl::x)
  326.                 }
  327.             }
  328.             }
  329.         }
  330.  
  331.         # Look through the packages that appeared, and if there is
  332.         # a version provided, then record it
  333.  
  334.         foreach ::tcl::x [package names] {
  335.             if {[string compare [package provide $::tcl::x] ""] \
  336.                 && ![info exists ::tcl::packages($::tcl::x)]} {
  337.             lappend ::tcl::newPkgs \
  338.                 [list $::tcl::x [package provide $::tcl::x]]
  339.             }
  340.         }
  341.         }
  342.     } msg] == 1} {
  343.         set what [$c eval set ::tcl::debug]
  344.         if {$doVerbose} {
  345.         tclLog "warning: error while $what $file: $msg"
  346.         }
  347.     } else {
  348.         set type [$c eval set ::tcl::type]
  349.         set cmds [lsort [$c eval array names ::tcl::newCmds]]
  350.         set pkgs [$c eval set ::tcl::newPkgs]
  351.         if {[llength $pkgs] > 1} {
  352.         tclLog "warning: \"$file\" provides more than one package ($pkgs)"
  353.         }
  354.         foreach pkg $pkgs {
  355.         # cmds is empty/not used in the direct case
  356.         lappend files($pkg) [list $file $type $cmds]
  357.         }
  358.  
  359.         if {$doVerbose} {
  360.         tclLog "processed $file"
  361.         }
  362.         interp delete $c
  363.     }
  364.     }
  365.  
  366.     append index "# Tcl package index file, version 1.1\n"
  367.     append index "# This file is generated by the \"pkg_mkIndex$more\" command\n"
  368.     append index "# and sourced either when an application starts up or\n"
  369.     append index "# by a \"package unknown\" script.  It invokes the\n"
  370.     append index "# \"package ifneeded\" command to set up package-related\n"
  371.     append index "# information so that packages will be loaded automatically\n"
  372.     append index "# in response to \"package require\" commands.  When this\n"
  373.     append index "# script is sourced, the variable \$dir must contain the\n"
  374.     append index "# full path name of this file's directory.\n"
  375.  
  376.     foreach pkg [lsort [array names files]] {
  377.     set cmd {}
  378.     foreach {name version} $pkg {
  379.         break
  380.     }
  381.     lappend cmd ::pkg::create -name $name -version $version
  382.     foreach spec $files($pkg) {
  383.         foreach {file type procs} $spec {
  384.         if { $direct } {
  385.             set procs {}
  386.         }
  387.         lappend cmd "-$type" [list $file $procs]
  388.         }
  389.     }
  390.     append index "\n[eval $cmd]"
  391.     }
  392.  
  393.     set f [open pkgIndex.tcl w]
  394.     puts $f $index
  395.     close $f
  396.     cd $oldDir
  397. }
  398.  
  399. # tclPkgSetup --
  400. # This is a utility procedure use by pkgIndex.tcl files.  It is invoked
  401. # as part of a "package ifneeded" script.  It calls "package provide"
  402. # to indicate that a package is available, then sets entries in the
  403. # auto_index array so that the package's files will be auto-loaded when
  404. # the commands are used.
  405. #
  406. # Arguments:
  407. # dir -            Directory containing all the files for this package.
  408. # pkg -            Name of the package (no version number).
  409. # version -        Version number for the package, such as 2.1.3.
  410. # files -        List of files that constitute the package.  Each
  411. #            element is a sub-list with three elements.  The first
  412. #            is the name of a file relative to $dir, the second is
  413. #            "load" or "source", indicating whether the file is a
  414. #            loadable binary or a script to source, and the third
  415. #            is a list of commands defined by this file.
  416.  
  417. proc tclPkgSetup {dir pkg version files} {
  418.     global auto_index
  419.  
  420.     package provide $pkg $version
  421.     foreach fileInfo $files {
  422.     set f [lindex $fileInfo 0]
  423.     set type [lindex $fileInfo 1]
  424.     foreach cmd [lindex $fileInfo 2] {
  425.         if {[string equal $type "load"]} {
  426.         set auto_index($cmd) [list load [file join $dir $f] $pkg]
  427.         } else {
  428.         set auto_index($cmd) [list source [file join $dir $f]]
  429.         } 
  430.     }
  431.     }
  432. }
  433.  
  434. # tclMacPkgSearch --
  435. # The procedure is used on the Macintosh to search a given directory for files
  436. # with a TEXT resource named "pkgIndex".  If it exists it is sourced in to the
  437. # interpreter to setup the package database.
  438.  
  439. proc tclMacPkgSearch {dir} {
  440.     foreach x [glob -nocomplain [file join $dir *.shlb]] {
  441.     if {[file isfile $x]} {
  442.         set res [resource open $x]
  443.         foreach y [resource list TEXT $res] {
  444.         if {[string equal $y "pkgIndex"]} {source -rsrc pkgIndex}
  445.         }
  446.         catch {resource close $res}
  447.     }
  448.     }
  449. }
  450.  
  451. # tclPkgUnknown --
  452. # This procedure provides the default for the "package unknown" function.
  453. # It is invoked when a package that's needed can't be found.  It scans
  454. # the auto_path directories and their immediate children looking for
  455. # pkgIndex.tcl files and sources any such files that are found to setup
  456. # the package database.  (On the Macintosh we also search for pkgIndex
  457. # TEXT resources in all files.)  As it searches, it will recognize changes
  458. # to the auto_path and scan any new directories.
  459. #
  460. # Arguments:
  461. # name -        Name of desired package.  Not used.
  462. # version -        Version of desired package.  Not used.
  463. # exact -        Either "-exact" or omitted.  Not used.
  464.  
  465. proc tclPkgUnknown {name version {exact {}}} {
  466.     global auto_path tcl_platform env
  467.  
  468.     if {![info exists auto_path]} {
  469.     return
  470.     }
  471.     # Cache the auto_path, because it may change while we run through
  472.     # the first set of pkgIndex.tcl files
  473.     set old_path [set use_path $auto_path]
  474.     while {[llength $use_path]} {
  475.     set dir [lindex $use_path end]
  476.     # we can't use glob in safe interps, so enclose the following
  477.     # in a catch statement, where we get the pkgIndex files out
  478.     # of the subdirectories
  479.     catch {
  480.         foreach file [glob -nocomplain [file join $dir * pkgIndex.tcl]] {
  481.         set dir [file dirname $file]
  482.         if {[file readable $file] && ![info exists procdDirs($dir)]} {
  483.             if {[catch {source $file} msg]} {
  484.             tclLog "error reading package index file $file: $msg"
  485.             } else {
  486.             set procdDirs($dir) 1
  487.             }
  488.         }
  489.         }
  490.     }
  491.     set dir [lindex $use_path end]
  492.     set file [file join $dir pkgIndex.tcl]
  493.     # safe interps usually don't have "file readable", nor stderr channel
  494.     if {([interp issafe] || [file readable $file]) && \
  495.         ![info exists procdDirs($dir)]} {
  496.         if {[catch {source $file} msg] && ![interp issafe]}  {
  497.         tclLog "error reading package index file $file: $msg"
  498.         } else {
  499.         set procdDirs($dir) 1
  500.         }
  501.     }
  502.     # On the Macintosh we also look in the resource fork 
  503.     # of shared libraries
  504.     # We can't use tclMacPkgSearch in safe interps because it uses glob
  505.     if {(![interp issafe]) && \
  506.         [string equal $tcl_platform(platform) "macintosh"]} {
  507.         set dir [lindex $use_path end]
  508.         if {![info exists procdDirs($dir)]} {
  509.         tclMacPkgSearch $dir
  510.         set procdDirs($dir) 1
  511.         }
  512.         foreach x [glob -nocomplain [file join $dir *]] {
  513.         if {[file isdirectory $x] && ![info exists procdDirs($x)]} {
  514.             set dir $x
  515.             tclMacPkgSearch $dir
  516.             set procdDirs($dir) 1
  517.         }
  518.         }
  519.     }
  520.     set use_path [lrange $use_path 0 end-1]
  521.     if {[string compare $old_path $auto_path]} {
  522.         foreach dir $auto_path {
  523.         lappend use_path $dir
  524.         }
  525.         set old_path $auto_path
  526.     }
  527.     }
  528. }
  529.  
  530. # ::pkg::create --
  531. #
  532. #    Given a package specification generate a "package ifneeded" statement
  533. #    for the package, suitable for inclusion in a pkgIndex.tcl file.
  534. #
  535. # Arguments:
  536. #    args        arguments used by the create function:
  537. #            -name        packageName
  538. #            -version    packageVersion
  539. #            -load        {filename ?{procs}?}
  540. #            ...
  541. #            -source        {filename ?{procs}?}
  542. #            ...
  543. #
  544. #            Any number of -load and -source parameters may be
  545. #            specified, so long as there is at least one -load or
  546. #            -source parameter.  If the procs component of a 
  547. #            module specifier is left off, that module will be
  548. #            set up for direct loading; otherwise, it will be
  549. #            set up for lazy loading.  If both -source and -load
  550. #            are specified, the -load'ed files will be loaded 
  551. #            first, followed by the -source'd files.
  552. #
  553. # Results:
  554. #    An appropriate "package ifneeded" statement for the package.
  555.  
  556. proc ::pkg::create {args} {
  557.     append err(usage) "[lindex [info level 0] 0] "
  558.     append err(usage) "-name packageName -version packageVersion"
  559.     append err(usage) "?-load {filename ?{procs}?}? ... "
  560.     append err(usage) "?-source {filename ?{procs}?}? ..."
  561.  
  562.     set err(wrongNumArgs) "wrong # args: should be \"$err(usage)\""
  563.     set err(valueMissing) "value for \"%s\" missing: should be \"$err(usage)\""
  564.     set err(unknownOpt)   "unknown option \"%s\": should be \"$err(usage)\""
  565.     set err(noLoadOrSource) "at least one of -load and -source must be given"
  566.  
  567.     # process arguments
  568.     set len [llength $args]
  569.     if { $len < 6 } {
  570.     error $err(wrongNumArgs)
  571.     }
  572.     
  573.     # Initialize parameters
  574.     set opts(-name)        {}
  575.     set opts(-version)        {}
  576.     set opts(-source)        {}
  577.     set opts(-load)        {}
  578.  
  579.     # process parameters
  580.     for {set i 0} {$i < $len} {incr i} {
  581.     set flag [lindex $args $i]
  582.     incr i
  583.     switch -glob -- $flag {
  584.         "-name"        -
  585.         "-version"        {
  586.         if { $i >= $len } {
  587.             error [format $err(valueMissing) $flag]
  588.         }
  589.         set opts($flag) [lindex $args $i]
  590.         }
  591.         "-source"        -
  592.         "-load"        {
  593.         if { $i >= $len } {
  594.             error [format $err(valueMissing) $flag]
  595.         }
  596.         lappend opts($flag) [lindex $args $i]
  597.         }
  598.         default {
  599.         error [format $err(unknownOpt) [lindex $args $i]]
  600.         }
  601.     }
  602.     }
  603.  
  604.     # Validate the parameters
  605.     if { [llength $opts(-name)] == 0 } {
  606.     error [format $err(valueMissing) "-name"]
  607.     }
  608.     if { [llength $opts(-version)] == 0 } {
  609.     error [format $err(valueMissing) "-version"]
  610.     }
  611.     
  612.     if { [llength $opts(-source)] == 0 && [llength $opts(-load)] == 0 } {
  613.     error $err(noLoadOrSource)
  614.     }
  615.  
  616.     # OK, now everything is good.  Generate the package ifneeded statment.
  617.     set cmdline "package ifneeded $opts(-name) $opts(-version) "
  618.     
  619.     set cmdList {}
  620.     set lazyFileList {}
  621.  
  622.     # Handle -load and -source specs
  623.     foreach key {load source} {
  624.     foreach filespec $opts(-$key) {
  625.         foreach {filename proclist} {{} {}} {
  626.         break
  627.         }
  628.         foreach {filename proclist} $filespec {
  629.         break
  630.         }
  631.         
  632.         if { [llength $proclist] == 0 } {
  633.         set cmd "\[list $key \[file join \$dir [list $filename]\]\]"
  634.         lappend cmdList $cmd
  635.         } else {
  636.         lappend lazyFileList [list $filename $key $proclist]
  637.         }
  638.     }
  639.     }
  640.  
  641.     if { [llength $lazyFileList] > 0 } {
  642.     lappend cmdList "\[list tclPkgSetup \$dir $opts(-name)\
  643.         $opts(-version) [list $lazyFileList]\]"
  644.     }
  645.     append cmdline [join $cmdList "\\n"]
  646.     return $cmdline
  647. }
  648.  
  649.